;mode800,value3099

;=defineڿʼ==========================
*define
caption "̰ĺз for ONScripter"
nsa
menusetwindow 24,24,2,2,0,1,#000000
savenumber 20
effect 2,10,300
effect 3,10,200
effect 4,11,200
effect 5,12,200
effect 6,17,500
effectcut
defaultspeed 10,5,1
underline 560
windowback
globalon
spi "nscrpng.spi|png"
transmode alpha
humanz 38

dim ?0[9]
dim ?1[9]
dim ?2[9]
dim ?3[9]
dim ?4[9]
dim ?5[9]
dim ?6[9]
dim ?7[9]
dim ?8[9]
dim ?9[9]
usewheel
maxkaisoupage 40
automode
automode_time 1200

textgosub *sys_first
pretextgosub *pretext
loadgosub *loadadjust

;
numalias scale,3099
numalias bgmvol,3100
numalias voicevol,3101
numalias sevol,3102
numalias textopa,3103

numalias back,11
numalias tag,12
numalias textwin,13
numalias back_loop,15
numalias back_tmp,16

;
numalias voice,8
numalias face,9
numalias name,10
numalias textframe,11

;籾־
numalias badflag_kanon,101
numalias btn,102
numalias flag_haru,103
numalias flag_kanon,104
numalias flag_mizuha,105
numalias flag_tubaki,106
numalias s_game_clear,3301
numalias s_kanon_clear,3302
numalias s_mizuha_clear,3303
numalias s_show_next_chapter,3304
numalias s_tubaki_clear,3305
numalias t_evcgmode,3306
numalias t_go_next_chapter,3307

;===============================

defsub cspa
defsub cspb
defsub csps
defsub cspmenu
defsub cspcbtn
defsub cspsel
defsub endlog
defsub movie
defsub vsp_btn0
defsub vsp_btn1
defsub vsp_sel0
defsub vsp_sel1
defsub textoff1
defsub texton1
defsub name
defsub namecl
defsub face
defsub setwin0
defsub setwin1
defsub setwin2
defsub setwin3
defsub allstop
defsub dwavestop_all
defsub voice
defsub novelvoice
defsub textbtn
defsub textbtn2
defsub wait2
defsub quake2
defsub flash
defsub lsps
defsub amsps
defsub frame
defsub presetfar
defsub endsetfar

defsub bgms
defsub dwave
defsub dwaveloop

;=defineڽ==========================

game

*start
rubyon
#000000
erasetextwindow 0

fileexist %0,"gloval.sav"
if %0==1 jumpf
mov %bgmvol,100
mov %voicevol,100
mov %sevol,100
mov %textopa,60
~

mov %scale,800
mov %tag,3000
goto *title

;===============================

*bgms
getparam $1
bgm $1
bgmvol %bgmvol
return

*dwave
getparam %0,$1
if %0 != 0 jumpf
_dwave 0,$1
chvol 0,%voicevol
return
~
_dwave %0,$1
chvol %0,%sevol
return

*dwaveloop
getparam %0,$1
_dwaveloop %0,$1
chvol %0,%sevol
return

*dwavestop_all
for %0=1 to 5
dwavestop %0
next
return

*allstop
bgmstop:dwavestop 0:dwavestop_all:monocro off:nega 0
return

*cspa
for %0=0 to 39
csp %0
next
return

*cspb
for %0=3 to 16
csp %0
next
return

*csps
getparam %1,%2
for %0=%1 to %1+%2
csp %0
next
return

*cspmenu
for %0=15 to 20
csp %0
next
return

*cspcbtn
for %0=3 to 12
csp %0
next
return

*cspsel
for %0=60 to 70
csp %0
next
return

*endlog
for %0=3 to 30
csp %0
next
return

*vsp_btn0
for %0=0 to 16
vsp %0,0
next
vsp2 39,0
vsp2 40,0
return

*vsp_btn1
for %0=0 to 2
vsp %0,1
next
vsp2 39,1
vsp2 40,1
print 1
texton
return

*vsp_sel0
for %0=60 to 70
vsp %0,0
next
return

*vsp_sel1
for %0=60 to 70
vsp %0,1
next
return

*voice
getparam $1
dwavestop 0
isskip %0
if %0==1 jumpf
dwave 0,"voice/"+$1+".ogg"
~
return

*novelvoice
getparam $1
dwavestop 0
add $%tag,","+$1
isskip %0
if %0==1 jumpf
dwave 0,"voice/"+$1+".ogg"
~
return

*wait2
getparam %1
isskip %0
if %0==1 jumpf
delay %1
~
return

*quake2
getparam %1,%2
isskip %0
if %0==1 jumpf
quake %1,%2
~
return

*movie
csp -1
getparam $2,%2
saveoff
fileexist %3,$2:if %3=0 return
split $2,".",$1:add $1,"-"

mov %1,0:mov %4,7
for %0=0 to 999999
itoa $0,%0:len %5,$0:mov %6,%4-%5
for %7=1 to %6:mov $0,"0"+$0:next
fileexist %3,$1+$0+".jpg"
if %3=1 inc %1
if %3=0 break
next

mov %0,0
lr_trap *movie_end
bgmonce $2
resettimer
for %0=1 to 999999
gettimer %3
itoa $0,%1*%3/%2:len %5,$0:mov %6,%4-%5
for %7=1 to %6:mov $0,"0"+$0:next
if %3>=%2 break
bg $1+$0+".jpg",1
;btndef $1+$0+".jpg":blt 0,0,800,600,0,0,800,600
next
goto *movie_end2

*movie_end
if %0>0 break:next
*movie_end2
lr_trap off
;ofscpy
bg black,1:stop
return

*textoff1
for %0=0 to 16
csp %0
next
vsp2 39,0
csp2 40
print 1
textoff
return

*texton1
vsp2 39,1
frame
print 1
texton
return


*name
getparam $1
if %textwin != 1 return
lsp 0,":s/23,23,1,2;#FFFFFF$1",105,410
print 1
return

*namecl
csp 0:csp 1:csp2 39
print 1
dwavestop 0
return

*face
getparam $1
lsps 39,"image/"+$1+".png",0,0,100,100,0,255
getspsize 39,%0,%1
amsps 39,0,600-%1,100,100,0,255
print 1
return

*setwin0
if %textwin == 0 return
if %textwin != 2 setwindow3 125,453,22,4,29,29,0,5,10,1,2,":l;image/dummy_frame.jpg",0,443
if %textwin == 2 setwindow 125,453,22,4,29,29,0,5,10,1,2,":l;image/dummy_frame.jpg",0,443
mov %textwin,0
!sd
#FFFFFF
textoff
return

*setwin1
if %textwin != 2 setwindow3 125,453,22,4,29,29,0,5,10,1,2,":l;image/dummy_frame.jpg",0,443
if %textwin == 2 setwindow 125,453,22,4,29,29,0,5,10,1,2,":l;image/dummy_frame.jpg",0,443
mov %textwin,0
frame
!sd
#FFFFFF
return

*setwin2
if %textwin != 2 setwindow3 125,453,22,4,29,29,0,5,10,1,2,":l;image/dummy_frame.jpg",0,443
if %textwin == 2 setwindow 125,453,22,4,29,29,0,5,10,1,2,":l;image/dummy_frame.jpg",0,443
mov %textwin,1
frame
!sd
#FFFFFF
return

*setwin3
if %textwin != 2 setwindow 40,85,24,11,29,29,0,6,10,1,2,":l;image/dummy_frame_novel.jpg",0,50
if %textwin == 2 setwindow3 40,85,24,11,29,29,0,6,10,1,2,":l;image/dummy_frame_novel.jpg",0,50
mov %textwin,2
mov $%tag,"voice"
frame
!sd
#FFFFFF
return

*frame
mov %0,%textopa*255/100
if %textwin == 0 lsps 40,":a;image/game_frame_avg.png",0,443,100,100,0,%0:return
if %textwin == 1 lsps 40,":a;image/game_frame_avg2.png",0,399,100,100,0,%0:return
if $textframe == "" lsps 40,":a;image/game_frame_novel.png",0,50,100,100,0,%0:return
lsps 40,":a;image/frame_"+$textframe+".png",0,34,100,100,0,%0
return

*textbtn
lsp 3,":a/3,0,3;image/game_history.png",411,579
lsp 4,":a/3,0,3;image/game_auto.png",438,579
lsp 5,":a/3,0,3;image/game_skip.png",463,579
lsp 6,":a/3,0,3;image/game_save.png",510,573
lsp 7,":a/3,0,3;image/game_load.png",560,573
lsp 8,":a/3,0,3;image/game_config.png",603,578
lsp 9,":a/3,0,3;image/game_qsave.png",645,583
lsp 10,":a/3,0,3;image/game_qload.png",697,583
lsp 11,":a/3,0,3;image/game_hide.png",755,411
if %textwin == 2 amsp 11,755,32
lsp 12,":a/3,0,3;image/game_voice.png",744,579
lsp 13,":a/3,0,3;image/game_hold.png",744,579
lsp 14,"image/game_base1.png",348,569
lsp 15,"image/game_base2.png",400,576
lsp 16,"image/game_base3.png",502,572
frame
print 1
return

*textbtn2
csp2 40
lsp 3,":a/3,0,3;image/game_history.png",411,579
lsp 4,":a/3,0,3;image/game_auto.png",438,579
lsp 5,":a/3,0,3;image/game_skip.png",463,579
lsp 6,":a/3,0,3;image/game_save.png",510,573
lsp 7,":a/3,0,3;image/game_load.png",560,573
lsp 8,":a/3,0,3;image/game_config.png",603,578
lsp 9,":a/3,0,3;image/game_qsave.png",645,583
lsp 10,":a/3,0,3;image/game_qload.png",697,583
lsp 11,":a/3,0,3;image/game_hide.png",755,411
if %textwin == 2 amsp 11,755,32
lsp 12,":a/3,0,3;image/game_voice.png",744,579
lsp 13,":a/3,0,3;image/game_hold.png",744,579
lsp 14,"image/game_base1.png",348,569
lsp 15,"image/game_base2.png",400,576
lsp 16,"image/game_base3.png",502,572
print 1
spbtn 3,3
spbtn 6,6
spbtn 7,7
spbtn 8,8
spbtn 9,9
savefileexist %0,21
if %0==1 spbtn 10,10
spbtn 11,11

return


*flash
getparam %1,%2,%3
csp %1:print 1:lsp %1,":c;visual/visual_white.png",0,0,%2
print 10,%3:csp %1:print 10,%3
return

*lsps
getparam %19,$3,%20,%21,%22,%23,%24,%25
lsph %19,$3,0,0,0
getspsize %19,%7,%8
csp %19
mov %20,%20+%7/2+1
mov %21,%21+%8/2+1
lsp2 %19,$3,%20,%21,%22,%23,%24,%25
return

*amsps
getparam %19,%20,%21,%22,%23,%24,%25
getspsize %19,%7,%8
mov %20,%20+%7/2+1
mov %21,%21+%8/2+1
amsp2 %19,%20,%21,%22,%23,%24,%25
return

*presetfar
;textoff1
for %0 = 90 to 99
csp %0
next
return

*endsetfar
for %0 = 90 to 99
csp2 %0
next
;texton1
return

;=ϵͳ==================

*loadadjust
dec %tag
if %textwin=0 setwin1
if %textwin=1 setwin2
if %textwin=2 setwin3:inc %tag
bgmvol %bgmvol
chvol 0,%voicevol
for %0=1 to 5
chvol %0,%sevol
next
return

*pretext
mov %1,0
gettag $0
if $0 != "" split $0,"|",%1,$name,$voice,$face
if %textwin == 2 goto *pretext2
if %1 == 1 inc %tag:mov $%tag,$0
if %tag = 3049 mov %tag,2999
if %1 == 1 && $voice != "" voice $voice
if %1 == 1 && $name != "" name $name:indent 1
if %1 == 1 && $name == "" indent 0
if %1 == 1 && $face != "" face $face
return

*pretext2
if %1 == 1 && $voice != "" novelvoice $voice
return

*sys_first
saveoff

*sys_btn
btndef clear

isskip %0
if %0 == 1 jumpf

textbtn
spbtn 3,3
spbtn 4,4
spbtn 5,5
spbtn 6,6
spbtn 7,7
spbtn 8,8
spbtn 9,9
savefileexist %0,21
if %0==1 spbtn 10,10
spbtn 11,11
if $voice != "" spbtn 12,12
~

textbtnwait %0
if %0=0 goto *sys_end
if %0=-1 vsp_btn0:systemcall windowerase:vsp_btn1:print 1:goto *sys_btn
if %0=-2 gosub *back_first:vsp_btn1:goto *sys_btn
if %0=-3 goto *sys_end
if %0=3 gosub *back_first:vsp_btn1:goto *sys_btn
if %0=4 systemcall automode:goto *sys_end
if %0=5 systemcall skip:goto *sys_end
if %0=6 vsp_btn0:gosub *save_first:vsp_btn1:goto *sys_btn
if %0=7 vsp_btn0:gosub *load_first:vsp_btn1:goto *sys_btn
if %0=8 cspb:gosub *config_first:goto *sys_btn
if %0=9 savegame 21:goto *sys_btn
if %0=10 loadgame 21
if %0=11 csp 11:vsp_btn0:systemcall windowerase:vsp_btn1:print 1:goto *sys_btn
if %0=12 voice $voice:goto *sys_btn
goto *sys_btn

*sys_end
btndef clear
vsp_btn1
ispage %0
texec
if %0 == 1 && %textwin != 2 namecl
if %0 == 1 && %textwin == 2 inc %tag:dwavestop 0:mov $%tag,"voice":if %tag == 3049 mov %tag,2999
saveon
return

;=======================================

*config_first
textoff1
lsp 60,":c;image/black.png",0,0,150

*config_loop
btndef clear
mov %5,1
itoa2 $1,%bgmvol
itoa2 $2,%voicevol
itoa2 $3,%sevol
itoa2 $4,%textopa

lsp 50,":s/24,24,1,2;#808080#FFFFFF£ǣ",100,150
lsp 51,":s/24,24,1,2;#808080#FFFFFF֣ϣɣã",100,200
lsp 52,":s/24,24,1,2;#808080#FFFFFFӣ",100,250
lsp 53,":s/24,24,1,2;#808080#FFFFFFףɣΣģϣ",100,300
lsp 54,":s/24,24,1,2;#808080#FFFFFFԣɣԣ̣",100,350

lsp 55,":s/24,24,1,2;#FFFFFF$1",300,150
lsp 56,":s/24,24,1,2;#FFFFFF$2",300,200
lsp 57,":s/24,24,1,2;#FFFFFF$3",300,250
lsp 58,":s/24,24,1,2;#FFFFFF$4",300,300

lsp 59,":s/24,24,1,2;#808080#FFFFFFţΣ",100,400

print 1

*btnloop
btndef clear
btndown 0
spbtn 50,50
spbtn 51,51
spbtn 52,52
spbtn 53,53
spbtn 54,54
spbtn 59,59

btnwait %0

if %0 == -1 gosub *cfg_end:return
if %0 == 50 gosub *set_bgmvol:goto *config_loop
if %0 == 51 gosub *set_voicevol:goto *config_loop
if %0 == 52 gosub *set_sevol:goto *config_loop
if %0 == 53 gosub *set_textopa:goto *config_loop
if %0 == 54 systemcall reset:goto *config_loop
if %0 == 59 systemcall end:goto *config_loop

goto *btnloop

*cfg_end
bgmvol %bgmvol
chvol 0,%voicevol
for %0=1 to 5
chvol %0,%sevol
next
for %0=50 to 60
csp %0
next
print 1
texton1
return

*set_bgmvol
	mov %3,55
	mov %4,bgmvol
	gosub *setting
return

*set_voicevol
	mov %3,56
	mov %4,voicevol
	gosub *setting
return

*set_sevol
	mov %3,57
	mov %4,sevol
	gosub *setting
return

*set_textopa
	mov %3,58
	mov %4,textopa
	gosub *setting
return

*setting

if %%4 > 100 mov %%4,100
if %%4 < 0 mov %%4,0
itoa2 $1,%%4

lsp %3,":s/24,24,1,2;#FFFFFF$1",300,150 + (%3-55) *  50
print 1

btndef clear
btndown 1
getcursor
btnwait %0

if %0 = 0 return
if %0 = -1 return
if %0 = -2 gosub *btnd:sub %%4,%5
if %0 = -3 gosub *btnd:add %%4,%5
if %0 = -40 gosub *btnd:sub %%4,%5
if %0 = -41 gosub *btnd:add %%4,%5
if %0 = -42 gosub *btnd:add %%4,%5
if %0 = -43 gosub *btnd:sub %%4,%5

mov %1,%0

goto *setting

*btnd
if %1 != %0 mov %5,1:mov %2,0:return
inc %2
if %2 >= 5 mov %5,5
if %2 >= 10 mov %5,10:mov %2,10
return

btnwait %0
if %0=-1 cspb:return
if %0=3 vsp_btn0:systemcall reset:vsp_btn1:goto *config_btn
if %0=4 vsp_btn0:systemcall end:vsp_btn1:goto *config_btn
if %0=5 cspb:return
goto *config_btn

*save_first
textoff1
systemcall save
return

*load_first
textoff1
systemcall load
return


;=======================================

*back_first
btndef clear
mov %back,1
checkpage %1,1
if %1=0 return
vsp 0,0
vsp_btn0
print 1
textoff
lsp 30,"image/history_bg.png",0,0
gosub *back_page

if %textwin != 2 lsp 3,":a/3,0,3;image/history_up.png",740,90
lsp 4,":a/3,0,3;image/history_up.png",740,120
lsp 5,":a/3,0,3;image/history_down.png",740,480
if %textwin != 2 lsp 6,":a/3,0,3;image/history_down.png",740,510
lsp 7,":a/3,0,3;image/game_hide.png",735,550
print 1

*back_btn

if %textwin != 2 spbtn 3,3
spbtn 4,4
spbtn 5,5
if %textwin != 2 spbtn 6,6
spbtn 7,7

btnwait %0
;if %0=0 endlog:return
if %0=-1 endlog:return
if %0=-2 inc %back:gosub *back_page
if %0=-3 && %back==1 endlog:return
if %0=-3 && %back!=1 dec %back:gosub *back_page
if %0=3 add %back,4:gosub *back_page
if %0=4 inc %back:gosub *back_page
if %0=5 && %back==1 endlog:return
if %0=5 && %back!=1 dec %back:gosub *back_page
if %0=6 sub %back,4:gosub *back_page
if %0=7 endlog:return
if %0=16 voice $15:gosub *back_page
if %0=18 voice $17:gosub *back_page
if %0=20 voice $19:gosub *back_page
if %0=22 voice $21:gosub *back_page
if %0=24 voice $23:gosub *back_page
if %0=26 voice $25:gosub *back_page
if %0=28 voice $27:gosub *back_page
goto *back_btn

*back_page
btndef clear

if %textwin == 2 goto *back_page2

if %back <= 1 mov %back,1

if %back < 5 jumpf
for %0=0 to 4;
checkpage %1,%back-%0
if %1=0 dec %back
next
~

checkpage %1,%back;
if %1=0 dec %back:return

for %0=15 to 29;
csp %0
next

if %back < 4 jumpf;
checkpage %1,%back+3
if %1=0 dec %back
~

for %back_loop=0 to 3

mov %back_tmp,%back+%back_loop

checkpage %1,%back_tmp
if %1=0 break

getlog $1,%back_tmp

mov %1,60*%scale/800
mov %2,(460-%back_loop*130)*%scale/800
mov %3,15+%back_loop*2
strsp %3,$1,%1,%2,28,5,22,22,0,5,1,2,#FFFFFF
mov %4,%tag-%back_tmp
if %4 < 3000 add %4,50
split $%4,"|",%0,$4,$%3,$6
mov %5,%3+1
mov %6,%3+8
if $4 != "" && %textwin == 1 mov $4,""+$4+""
if %textwin != 1 mov $4,""
if $%3 != "" && $4 == "" && %textwin == 1 add $4,"?"
if $%3 != "" && %textwin != 1 mov $4,"?"
if $4 != "" lsp %5,":s/22,22,1,2;#FFFFFF#00008b$4",60,435-%back_loop*130
if $%3 != "" spbtn %5,%5

next

print 1
return
;================-

*back_page2

if %back <= 1 mov %back,1

checkpage %1,%back
if %1=0 dec %back:return

for %0=15 to 29
csp %0
next

getlog $1,%back

mov %1,55*%scale/800
mov %2,90*%scale/800
strsp 15,$1,%1,%2,31,15,20,20,0,9,1,2,#FFFFFF

mov %back_tmp,%tag-%back
if %back_tmp < 2999 add %back_tmp,50

split $%back_tmp,",",$2000,$2001,$2002,$2003,$2004,$2005,$2006,$2007,$2008

for %0=0 to 8
	mov %1,%0+2001:mov %2,%0*2+15:mov %3,%2+1
	if $%1 == "" break
	mov $%2,$%1
	lsp %3,":s/22,22,1,2;#FFFFFF#00008b?",60+%0*30,560
	spbtn %3,%3
next
mov %0,100
print 1
return

;=ר==============================


;===================================

*title
saveoff
csp -1
mov %textwin,1
setwin0

*L_title;title.ks
allstop
lsp 95,"image/black.png",0,0
print 10,300
saveoff
csp 93
lsps 93,"image/logo_ab2.png",0,0,100,100,0,255
csp 94
lsps 94,"image/logo_akabei.png",0,0,100,100,0,255
resettimer
for %1=1 to 999999
gettimer %2
if %2>=500 break
mov ?0[0],%2
mov ?3[0],0+(255-(0))*?0[0]/500
mov ?4[0],198+(198-(198))*?0[0]/500
mov ?5[0],126+(166-(126))*?0[0]/500
mov ?6[0],300+(120-(300))*?0[0]/500
mov ?7[0],0+(0-(0))*?0[0]/500
amsps 93,?4[0],?5[0],?6[0],?6[0],?7[0],?3[0]
mov ?0[1],%2
mov ?3[1],0+(255-(0))*?0[0]/500
mov ?4[1],400+(400-(400))*?0[0]/500
mov ?5[1],300+(300-(300))*?0[0]/500
mov ?6[1],10+(90-(10))*?0[0]/500
mov ?7[1],0+(0-(0))*?0[0]/500
amsp2 94,?4[1],?5[1],?6[1],?6[1],?7[1],?3[1]
print 1
next
amsps,93,198,166,120,120,0,255
amsp2,94,400,300,90,90,0,255
print 1

wait 500
rnd %0,7
rnd %0,7
if %0=0 voice "tub_0318"
if %0=1 voice "gon_0074"
if %0=2 voice "miz_0039"
if %0=3 voice "kan_0208"
if %0=4 voice "eii_0304"
if %0=5 voice "har_0546"
if %0=6 voice "mao_f"
lsps 90,"image/white.png",0,0,100,100,0,255

print 10,1000

*L_title_title_init

csp2 -1
csp -1
textoff1

*L_title_start_title

notif %s_game_clear == 1 goto *else1
	notif %s_show_next_chapter == 1 goto *else2
		lsp 100,"image/t_bg2_next.png",0,0
		goto *end2
	*else2
		lsp 100,"image/t_bg2.png",0,0
		goto *end2
	*end2
	goto *end1
*else1
	notif %s_show_next_chapter == 1 goto *else3
		lsp 100,"image/t_bg_next.png",0,0
		goto *end3
	*else3
		lsp 100,"image/t_bg.png",0,0
		goto *end3
	*end3
	goto *end1
*end1

mov %0,%s_kanon_clear+%s_tubaki_clear+%s_mizuha_clear+%s_game_clear
if %0=0 bgms "bgm/bgm_110.ogg"
if %0=1 bgms "bgm/bgm_110a.ogg"
if %0=2 bgms "bgm/bgm_110c.ogg"
if %0=3 bgms "bgm/bgm_110e.ogg"
if %0=4 bgms "bgm/bgm_110f.ogg"

*title_btn
if %s_show_next_chapter = 1 lsp 10,":a/3,0,3;image/t_next.png",226,279
lsp 4,":a/3,0,3;image/t_start.png",277,334
lsp 5,":a/3,0,3;image/t_load.png",277,380
lsp 6,":a/3,0,3;image/t_config.png",279,425
lsp 7,":a/3,0,3;image/t_extra.png",276,470
lsp 8,":a/3,0,3;image/t_exit.png",278,517

print 10,1000

*title_btn_loop
btndef clear

spbtn 4,4
spbtn 5,5
spbtn 6,6
spbtn 8,8
spbtn 10,10

btnwait %0

if %0=4 goto *initial
if %0=5 systemcall load
if %0=6 gosub *config_first:csp2 40:print 1:goto *title_btn
if %0=8 end
if %0=10 goto *nextchapter
goto *title_btn_loop


*initial

setwin0

mov %101,0
mov %102,0
mov %103,0
mov %104,0
mov %105,0
mov %106,0
mov %107,0

csp -1
print 10,2000
bgmstop
goto *L_g01

*nextchapter
csp -1
print 10,2000
mov %t_go_next_chapter,1
loadgame 22


*L_staffroll_text
csp -1
csp -2
allstop
bgmonce "bgm/bgm_end.ogg"
lsp 100,"image/t_logo.png",150,150
print 10,2000
wait 10000
click
csp 100
print 10,2000
return

